Warning: chmod(): Operation not permitted in /var/www/hopeinstoughton_www/wp-content/plugins/simple-universal-google-analytics/main.php on line 8
[0] in function chmod in /var/www/hopeinstoughton_www/wp-content/plugins/simple-universal-google-analytics/main.php on line 8
[1] in function include_once in /var/www/hopeinstoughton_www/wp-settings.php on line 560
[2] in function require_once in /var/www/hopeinstoughton_www/wp-config.php on line 85
[3] in function require_once in /var/www/hopeinstoughton_www/wp-load.php on line 50
[4] in function require_once in /var/www/hopeinstoughton_www/wp-blog-header.php on line 13
[5] in function require in /var/www/hopeinstoughton_www/index.php on line 17

#!/usr/bin/perl -w
# This program searches for the given Perl regular expression in a Zip archive.
# Archive is assumed to contain text files.
# By Ned Konz, perl@bike-nomad.com
# Usage:
# 	perl zipGrep.pl 'pattern' myZip.zip
#
use strict;
use Archive::Zip qw(:CONSTANTS :ERROR_CODES);

if (@ARGV != 2) {
    print <<EOF;
This program searches for the given Perl regular expression in a Zip archive.
Archive is assumed to contain text files.
Usage:
	perl $0 'pattern' myZip.zip
EOF
    exit 1;
}

my $pattern = shift;
$pattern = qr{$pattern};    # compile the regular expression
my $zipName = shift;

my $zip = Archive::Zip->new();
if ($zip->read($zipName) != AZ_OK) {
    die "Read error reading $zipName\n";
}

foreach my $member ($zip->members()) {
    my ($bufferRef, $status, $lastChunk);
    my $memberName = $member->fileName();
    my $lineNumber = 1;
    $lastChunk = '';
    $member->desiredCompressionMethod(COMPRESSION_STORED);
    $status = $member->rewindData();
    die "rewind error $status" if $status != AZ_OK;

    while (!$member->readIsDone()) {
        ($bufferRef, $status) = $member->readChunk();
        die "readChunk error $status"
          if $status != AZ_OK && $status != AZ_STREAM_END;

        my $buffer = $lastChunk . $$bufferRef;
        while ($buffer =~ m{(.*$pattern.*\n)}mg) {
            print "$memberName:$1";
        }
        ($lastChunk) = $$bufferRef =~ m{([^\n\r]+)\z};
    }

    $member->endRead();
}